16.1 Aantal cliënten met het syndroom van Korsakov

Concepten

• Vestiging
• Vestigingsnummer
• ZorgDeclaratie
• Zorgkantoor regio
• Zorgproces

Relaties

• deel van
• gaat over
• geïdentificeerd door
• heeft deel
• heeft deelnemer
• heeft lokaliseerbaar gebied
• heeft perdurantlocatie
• opereert in regio
• vestiging van

Eigenschappen

• einddatum
• goedgekeurd
• heeft datawaarde
• heeftZorgPrestatieCode
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: Zorgkantoren 16.1.0
2# Parameters: ?peildatum, ?zorgkantoor
3# Ontologie: versie 3.0.0 of nieuwer
4
5PREFIX onz-g: <http://purl.org/ozo/onz-g#>
6PREFIX onz-org: <http://purl.org/ozo/onz-org#>
7PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
8PREFIX onz-fin: <http://purl.org/ozo/onz-fin#>
9PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
10PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
11
12SELECT ?vestiging (COUNT(DISTINCT ?client) AS ?aantal_clienten)
13{
14    # BIND($(peildatum) AS ?peildatum)
15    VALUES ?prestatiecode { 
16        "EX001"
17        "EX003"
18        "EX004"
19    }
20    
21    ?declaratie
22        a onz-g:CareInvoice ;
23        onz-fin:heeftZorgPrestatieCode ?prestatiecode ;
24        onz-g:goedgekeurd "true"^^xsd:boolean ;
25        onz-g:isAbout ?zorgproces .
26    
27    ?zorgproces
28        a onz-zorg:ZorgProces ;
29        onz-g:hasParticipant ?client ;
30        onz-g:startDatum ?start_zorgproces ;
31        onz-g:hasPerdurantLocation ?locatie .
32    OPTIONAL { ?zorgproces onz-g:eindDatum ?eind_zorgproces .}
33    FILTER (?start_zorgproces <= ?peildatum && ((?eind_zorgproces >= ?peildatum) || (!BOUND(?eind_zorgproces))) )
34     
35     # selecteer vestiging van zorgproces
36    {
37        ?locatie
38            onz-g:partOf* ?vestiging_uri .
39        ?vestiging_uri a onz-org:Vestiging ;
40                        onz-g:hasLocalizableArea/onz-g:identifiedBy/onz-g:hasPart/onz-g:hasPart ?postcode_6 .
41        BIND(IRI(SUBSTR(STR(?postcode_6), 1, STRLEN(STR(?postcode_6)) - 2)) AS ?postcode)
42        ?pc_gebied 
43            onz-g:identifiedBy ?postcode ;
44            onz-g:partOf+ ?zk_regio .
45        ?zk_regio a onz-org:ZorgkantoorRegio .
46        ?zorgkantoor onz-g:hasOperatingRange ?zk_regio .
47        
48        {
49            ?vestiging_uri onz-g:identifiedBy ?vest_nr .
50            ?vest_nr a onz-org:Vestigingsnummer ;
51                onz-g:hasDataValue ?vestiging .
52        } UNION {
53            # Includeer ook de organisatie als geheel en label deze als vestiging
54            ?vestiging_uri onz-org:vestigingVan ?organisatie_uri .
55            BIND("Totaal organisatie" AS ?vestiging)
56            BIND("n.v.t." AS ?zk_vestiging)
57        }
58        BIND(IF(!BOUND(?zk_vestiging), ?zorgkantoor, ?zk_vestiging) AS ?zorgkantoor_vestiging)
59    }
60}
61GROUP BY ?vestiging ?zorgkantoor_vestiging
62ORDER BY ?vestiging
63